VS2005

岡山勉強会－第２回開催決定！

うなまな — Tue, 08 Jul 2008 23:20:00 GMT

やっと、岡山勉強会－第２回を開催することが決定しました。
詳細・参加登録などは、以下を参照してください。

http://oitec.vbstation.net/modules/eguide/event.php?eid=1

岡山・IT・エンジニアズ・コミュニティ立ち上げ

うなまな — Wed, 02 Jul 2008 22:17:00 GMT

Okayama IT Engineers Community
というコミュニティを立ち上げました。

http://oitec.vbstation.net/

興味にある方は、ぜひ、ユーザ登録してください。岡山県以外の方ももちろんＯＫです。

Visual Basic Power Packs 3.0

うなまな — Tue, 25 Mar 2008 00:12:00 GMT

リリースされていましたね。
一番実装してほしかった、DataRepeater Control が実装されてました。

Visual Basic Power Packs 3.0
http://www.microsoft.com/downloads/details.aspx?FamilyId=371368A8-7FDC-441F-8E7D-FE78D96D4063&displaylang=en

細かく機能を確認していませんが、VB6時代のDataRepeaterと、ほぼ同じ
ことができそうです。本家サイトでTips公開しなければ・・・

岡山で勉強会！

うなまな — Wed, 27 Feb 2008 23:53:00 GMT

このたび、岡山にてコミュニティ支援団体であるNPO法人アイネタジャパンと
マイクロソフトが共催で勉強会を開催します。

・日時 2008 年 3 月 22 日 (土) 13:00～18:30 (受付開始 12:30)
・会場第一セントラルビル 3F 中ホール (岡山県岡山市) [詳細MAP]

岡山でのイベントは初めてなのですが、今後、定期的に行えるように
してく予定です。

詳細は、http://msevents.microsoft.com/CUI/EventDetail.aspx?culture=en-US&EventID=1032370662

Vistaの音声合成は英語のみ？

うなまな — Mon, 05 Mar 2007 06:14:00 GMT

Vistaの音声合成は標準では、Microsoft Annaなので日本語を認識しない・・・
なので、Office2003で提供されているKenjiを利用してみるとうまく日本語を話す。
これでマイクロソフトナレータも利用できますね。

ナレータを利用したいんでなくて、System.Speech名前空間を利用したプログラムで
遊びたかっただけなのだが、SpeakProgressイベントなどが日本語だとダメみたい。

SAPI5.3の情報も少ないし、Microsoft Anna以外の音声はいものか・・・("Takashi","Keiko"?)

Visual Studio Code Name "Orcas" - March 2007 CTPが・・・

うなまな — Thu, 01 Mar 2007 05:50:00 GMT

http://www.microsoft.com/downloads/details.aspx?FamilyID=B533619A-0008-4DD6-9ED1-47D482683C78&displaylang=en

と

http://www.microsoft.com/downloads/details.aspx?FamilyID=281fcb3d-5e79-4126-b4c0-8db6332de26e&DisplayLang=en

は別モノなのか？

TableAdapterにトランザクションを実装

うなまな — Tue, 13 Feb 2007 00:23:00 GMT

TableAdapterでTransactionを行うには、TransactionScopeを利用するのが一番簡単だと思いますけど、みなさんはTableAdapterでTransactionを行うのをどのようにされていますか？
複数のTableAdapterにトランザクションを実装したりするのも・・・
以下のようなクラスを作ってテスト中・・・

Imports System.Data.SqlClient
Imports System.Reflection
''' <summary>
''' TableAdapterにトランザクション機能を実装するクラス
''' </summary>
''' <remarks>
''' 利用方法の例
'''    Dim tat As New TableAdapterTransactor
'''    Dim taData1 As New Data1TableAdapter
'''    Dim taData2 As New Data2TableAdapter
'''    
'''    tat.AddTableAdapter(taData1)
'''    tat.AddTableAdapter(taData2)
'''    tat.BeginTransaction()
'''    Try
'''        taData1.Insert......
'''        taData2.Insert......
'''        tat.Commit()
'''    Catch ex As Exception
'''        tat.Rollback()
'''    End Try
''' </remarks>
Public Class TableAdapterTransactor
    Private _conn As SqlConnection = Nothing
    Private _trans As SqlTransaction = Nothing
    Private _tableAdapters As New List(Of Object)
#Region "Pプロシージャ - GetConnection                     [TableAdapterのConnectionを取得する]"
    ''' <summary>
    ''' TableAdapterのConnectionを取得する
    ''' </summary>
    ''' <param name="tableAdapter">TableAdapter</param>
    ''' <returns>取得したConnection</returns>
    ''' <remarks></remarks>
    Private Function GetConnection(ByVal tableAdapter As Object) As SqlConnection
        Dim type As Type = tableAdapter.GetType()
        Dim connectionProperty As PropertyInfo = _
            type.GetProperty("Connection", BindingFlags.NonPublic Or BindingFlags.Instance)
        Dim connection As SqlConnection = _
            CType(connectionProperty.GetValue(tableAdapter, Nothing), SqlConnection)
        Return connection
    End Function
#End Region
#Region "Pプロシージャ - SetConnection                     [TableAdapterのConnectionを設定する]"
    ''' <summary>
    ''' TableAdapterのConnectionを設定する
    ''' </summary>
    ''' <param name="tableAdapter">TableAdapter</param>
    ''' <param name="connection">Connection</param>
    ''' <remarks></remarks>
    Private Sub SetConnection(ByVal tableAdapter As Object, ByVal connection As SqlConnection)
        Dim type As Type = tableAdapter.GetType()
        Dim connectionProperty As PropertyInfo = _
            type.GetProperty("Connection", BindingFlags.NonPublic Or BindingFlags.Instance)
        connectionProperty.SetValue(tableAdapter, connection, Nothing)
    End Sub
#End Region
#Region "Pプロシージャ - GetAdapter                        [TableAdapterのDataAdapterを取得する]"
    ''' <summary>
    ''' TableAdapterのDataAdapterを取得する
    ''' </summary>
    ''' <param name="tableAdapter">TableAdapter</param>
    ''' <returns>取得したDataAdapter</returns>
    ''' <remarks></remarks>
    Private Function GetAdapter(ByVal tableAdapter As Object) As SqlDataAdapter
        Dim type As Type = tableAdapter.GetType()
        Dim adapterProperty As PropertyInfo = _
            type.GetProperty("_adapter", BindingFlags.NonPublic Or BindingFlags.Instance)
        Dim adapter As SqlDataAdapter = _
            CType(adapterProperty.GetValue(tableAdapter, Nothing), SqlDataAdapter)
        Return adapter
    End Function
#End Region
#Region "Pプロシージャ - SetAdapter                        [TableAdapterのDataAdapterを設定する]"
    ''' <summary>
    ''' TableAdapterのDataAdapterを設定する
    ''' </summary>
    ''' <param name="tableAdapter">TableAdapter</param>
    ''' <param name="adapter">DataAdapter</param>
    ''' <remarks></remarks>
    Private Sub SetAdapter(ByVal tableAdapter As Object, ByVal adapter As SqlDataAdapter)
        Dim type As Type = tableAdapter.GetType()
        Dim adapterProperty As PropertyInfo = _
            type.GetProperty("_adapter", BindingFlags.NonPublic Or BindingFlags.Instance)
        adapterProperty.SetValue(tableAdapter, adapter, Nothing)
    End Sub
#End Region
#Region "Pプロシージャ - InitAdapter                       [TableAdapterのInitAdapterメソッドを呼び出す]"
    ''' <summary>
    ''' TableAdapterのInitAdapterメソッドを呼び出す
    ''' </summary>
    ''' <param name="tableAdapter">TableAdapter</param>
    ''' <remarks>利用しない</remarks>
    Private Sub InitAdapter(ByVal tableAdapter As Object)
        Dim type As Type = tableAdapter.GetType()
        Dim mi As MethodInfo = _
            type.GetMethod("InitAdapter", BindingFlags.NonPublic Or BindingFlags.Instance)
        mi.Invoke(tableAdapter, Nothing)
    End Sub
#End Region
#Region "Pプロシージャ - InitCommandCollection             [TableAdapterのInitCommandCollectionメソッドを呼び出す]"
    ''' <summary>
    ''' TableAdapterのInitCommandCollectionメソッドを呼び出す
    ''' </summary>
    ''' <param name="tableAdapter">TableAdapter</param>
    ''' <remarks>利用しない</remarks>
    Private Sub InitCommandCollection(ByVal tableAdapter As Object)
        Dim type As Type = tableAdapter.GetType()
        Dim mi As MethodInfo = _
            type.GetMethod("InitCommandCollection", BindingFlags.NonPublic Or BindingFlags.Instance)
        mi.Invoke(tableAdapter, Nothing)
    End Sub
#End Region
#Region "Pプロシージャ - SetTransactionCommands            [TableAdapterのCommandCollectionのTransactionを設定する]"
    ''' <summary>
    ''' TableAdapterのCommandCollectionのTransactionを設定する
    ''' </summary>
    ''' <param name="tableAdapter">TableAdapter</param>
    ''' <param name="transaction">Transaction</param>
    ''' <remarks></remarks>
    Private Sub SetTransactionCommands(ByVal tableAdapter As Object, ByVal transaction As SqlTransaction)
        Dim type As Type = tableAdapter.GetType()
        Dim commandsProperty As PropertyInfo = _
            type.GetProperty("CommandCollection", BindingFlags.NonPublic Or BindingFlags.Instance)
        Dim commands As SqlCommand() = _
            CType(commandsProperty.GetValue(tableAdapter, Nothing), SqlCommand())
        For Each command As SqlCommand In commands
            command.Transaction = transaction
        Next
        Me.SetConnection(tableAdapter, transaction.Connection)
    End Sub
#End Region
#Region "Pプロシージャ - SetTransactionAdapter             [TableAdapterのDataAdapterのTransactionを設定する]"
    ''' <summary>
    ''' TableAdapterのDataAdapterのTransactionを設定する
    ''' </summary>
    ''' <param name="tableAdapter">TableAdapter</param>
    ''' <param name="transaction">Transaction</param>
    ''' <remarks></remarks>
    Private Sub SetTransactionAdapter(ByVal tableAdapter As Object, ByVal transaction As SqlTransaction)
        Dim adp As SqlDataAdapter = Me.GetAdapter(tableAdapter)
        If adp.InsertCommand IsNot Nothing Then
            adp.InsertCommand.Transaction = transaction
        End If
        If adp.DeleteCommand IsNot Nothing Then
            adp.DeleteCommand.Transaction = transaction
        End If
        If adp.UpdateCommand IsNot Nothing Then
            adp.UpdateCommand.Transaction = transaction
        End If
        Me.SetAdapter(tableAdapter, adp)
        'Me.InitCommandCollection(tableAdapter)
    End Sub
#End Region
#Region "メソッド - AddTableAdapter                        [TableAdapterを追加する]"
    ''' <summary>
    ''' TableAdapterを追加する
    ''' </summary>
    ''' <param name="tableAdapter">TableAdapter</param>
    ''' <remarks></remarks>
    Public Sub AddTableAdapter(ByVal tableAdapter As Object)
        Me._tableAdapters.Add(tableAdapter)
    End Sub
#End Region
#Region "メソッド - BeginTransaction                       [トランザクションを開始する]"
    ''' <summary>
    ''' トランザクションを開始する
    ''' </summary>
    ''' <remarks>開始する前に、AddTableAdapterメソッドで対象となるTableAdapterを追加すること</remarks>
    Public Sub BeginTransaction()
        Dim counter As Integer = 0
        For Each adapter As Object In Me._tableAdapters
            counter += 1
            If counter = 1 Then
                Me._conn = Me.GetConnection(adapter)
                If Me._conn.State <> ConnectionState.Open Then
                    Me._conn.Open()
                End If
                Me._trans = Me._conn.BeginTransaction()
            End If
            Me.SetConnection(adapter, Me._conn)
            Me.SetTransactionAdapter(adapter, Me._trans)
            Me.SetTransactionCommands(adapter, Me._trans)
        Next
    End Sub
    ''' <summary>
    ''' トランザクションを開始する
    ''' </summary>
    ''' <param name="conn">コネクション</param>
    ''' <remarks></remarks>
    Public Sub BeginTransaction(ByVal conn As SqlConnection)
        Me._conn = conn
        If Me._conn.State <> ConnectionState.Open Then
            Me._conn.Open()
        End If
        Me._trans = Me._conn.BeginTransaction()
        For Each adapter As Object In Me._tableAdapters
            Me.SetConnection(adapter, Me._conn)
            Me.SetTransactionAdapter(adapter, Me._trans)
            Me.SetTransactionCommands(adapter, Me._trans)
        Next
    End Sub
    ''' <summary>
    ''' トランザクションを開始する
    ''' </summary>
    ''' <param name="trans">トランザクション</param>
    ''' <remarks></remarks>
    Public Sub BeginTransaction(ByVal trans As SqlTransaction)
        Me._conn = trans.Connection
        Me._trans = trans
        For Each adapter As Object In Me._tableAdapters
            Me.SetConnection(adapter, Me._conn)
            Me.SetTransactionAdapter(adapter, Me._trans)
            Me.SetTransactionCommands(adapter, Me._trans)
        Next
    End Sub
#End Region
#Region "メソッド - Commit                                 [トランザクションをコミットする]"
    ''' <summary>
    ''' トランザクションをコミットする
    ''' </summary>
    ''' <remarks></remarks>
    Public Sub Commit()
        Try
            Me._trans.Commit()
        Catch ex As Exception
            Me._trans.Rollback()
            Throw ex
        Finally
            If (Me._conn.State = ConnectionState.Open) Then
                Me._conn.Close()
            End If
        End Try
    End Sub
#End Region
#Region "メソッド - Rollback                               [トランザクションをロールバックする]"
    ''' <summary>
    ''' トランザクションをロールバックする
    ''' </summary>
    ''' <remarks></remarks>
    Public Sub Rollback()
        Me._trans.Rollback()
        If (Me._conn.State = ConnectionState.Open) Then
            Me._conn.Close()
        End If
    End Sub
#End Region
End Class

Visual Basic 2005 Power Packs

うなまな — Fri, 19 Jan 2007 08:16:00 GMT

Visual Basic 2005 Power Packs便利なものがあったんですね。
・Microsoft Printer Compatibility Library 1.0
・Microsoft Interop Forms Toolkit 1.0
・Microsoft PrintForm Component 1.0

VB6時代の資産にPrinterオブジェクトでゴリゴリ書いて印刷していたものを、.NETへ移行するのは大変だけど、 Microsoft Printer Compatibility Library 1.0 を入れれば、幸せになれそうですね。

今後も便利なツールが提供されそうなので、要チェックですね。

2007年には岡山で勉強会を開催したい

うなまな — Tue, 09 Jan 2007 22:36:00 GMT

2007年中には、岡山県内で勉強会を開催したいと思っています。
勉強会開催にこぎつけるため、まずは、アンケートを取りたいと思います。
アンケートにご協力お願い致します。

勉強会へ参加していただくターゲットはVB開発者の方々と考えております。
他に講師など協力していただける方がいれば、ターゲット層も広まるんですが・・・
勉強会開催に協力していただける方がいれば、ご連絡頂ければと思います。

WPFのObjectDataProviderのConstructorParameters、MethodParameters

うなまな — Thu, 12 Oct 2006 00:44:00 GMT

VSでXAMLにて記述する時に、インテリセンスに表示されない・・・
まぁ、表示時に下波線で警告されるけど、コンパイルできるんで問題ないんですけどね。
最新のCTPで改善されてると期待してたんですけどね。Ciderの起動が早くなったような。

コントロール配置後にコード内にイベントを記述する時に、配置されたコントロールが反映されていない。。。
一度コンパイルする必要があるのか？